StrictPolicy.idl

Go to the documentation of this file.

#ifndef _strict_policy_idl
#define _strict_policy_idl

/**
 * @file StrictPolicy.idl
 *
 * IDL file for the StrictPolicy sub-interface.
 *
 * @todo Rename the file to something appropriate, like BrokerPolicies.idl.
 */

#include "Broker.idl"

/**
 * Name space for subclasses of Broker::Policy.
 */
module BrokerPolicies
{
    /**
     * A simple strict priority-based contention policy.  The priority is a
     * signed integer where larger values indicate a higher priority.
     *
     * @sa StrictPolicyImpl
     */
    interface StrictPolicy : Broker::Policy
    {
        /**
         * Set the priority of a task.
         *
         * @param task The task whose priority should be changed.
         * @param priority The new priority.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        void SetTaskPriority(in Broker::Task task, in short priority);
    
        /**
         * Get the priority of a task.
         *
         * @param task The task whose priority should be retrieved.
         * @return The task's priority.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        short GetTaskPriority(in Broker::Task task);
    };

    /**
     * A contention policy based on weights, where the weight is the task's
     * proportional share.
     *
     * @sa WeightedPolicyImpl
     */
    interface WeightedPolicy : Broker::Policy
    {
        /**
         * Set the weight of a task.
         *
         * @param task The task whose priority should be changed.
         * @param weight The new weight.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        void SetTaskWeight(in Broker::Task task, in unsigned short weight);

        /**
         * Get the weight of a task.
         *
         * @param task The task whose weight should be retrieved.
         * @return The task's weight.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        unsigned short GetTaskWeight(in Broker::Task task);
    };
    
    /**
     * A contention policy that delegates decisions to zero or more
     * subpolicies.
     *
     * @sa PartitionPolicyImpl
     */
    interface PartitionPolicy : Broker::Policy
    {
        /**
         * The default policy to attach tasks to when they are added to a
         * manager.
         */
        attribute Broker::Policy DefaultPolicy;

        /**
         * Set the subpolicy for a task.
         *
         * @param task The task whose policy should be changed.
         * @param bp The new policy.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        void SetTaskPolicy(in Broker::Task task, in Broker::Policy bp);

        /**
         * Get the subpolicy for a task.
         *
         * @param task The task whose policy should be retrieved.
         * @return The task's policy.
         *
         * @exception CORBA::BAD_PARAM if task is nil.
         * @exception CORBA::BAD_PARAM if task is not managed by this policy.
         */
        Broker::Policy GetTaskPolicy(in Broker::Task task);
    };
};

#endif

---